How'd they make the #commands not show up in the chat menu?

[bigbigger9]

My long title pretty much says it all, How'd they make the #commands not show up in the chat menu?

Hope you can fill me in on this neat trick.

[Hersh]

I'm geussing it has a lot to do with this. (From comchat.cs)

Code: [Select]

if(String::getSubStr(%message, 0, 1) == "#")
%isCommand = True;So every time someone says something with # at the begining it calls it a Command.

Code: [Select]

%w1 = GetWord(%message, 0);
%cropped = String::NEWgetSubStr(%message, (String::len(%w1)+1), 99999);

if(%isCommand)
{
if(%w1 == "#Whatever")
{
                        Do Something
                                }
                }



The first part is just finding the key words.
But if(%isCommand) goes back up to the other code, where it starts with #. Well, typing in one of the words that equal %w1 will do "whatever" They won't return to the chat box. (They do whats in the if.) Searching for and finding the # on the beginning stops it from being normal chat.

Hersh

[bigbigger9]

Yea, but how did they get it so it doesn't show up in the chat window?

Edit: Erm, just need further explaination.

[UnderGod]

If you look in the remotesay function in comchat.cs it explains everything. If the message contains "#" at the beginning, %iscommand = True. In the function it basicly says to overide the rest of the chat function if %iscommand = True. If %iscommand = True, it checks the list of commands for what to do. If it isn't in the list of commands, then it just returns false doing nothing at all.

[Dragoon]

actually, it's the return;

if you run a command through, and then you put return; before the command is over, it won't show up in the chat window.

Code: [Select]

if(%w1 == "#news")
{
Client::sendMessage(%TrueClientId, 3, $Server::NewsOfTheDay);
return;
}


that would show up in only the client's chat window of the client who called for the news, because the return stops the message from going anywhere else.

[UnderGod]

That is almost exactly what I said.

[Dragoon]

don't write things out when visuals make it easier to see.

[UnderGod]

He asked for explaination =)

[bigbigger9]

heh, Undergod helped more. )

Thanks in advance.

[Silvanoshei]

Out of curiosity, um... Why?

[UnderGod]

Post the entire remotesay function from base tribes, adn i'll show you

[Hersh]

99% sure its base, and either way, its not RPG.

Hersh

Code: [Select]


function remoteSay(%clientId, %team, %message)
{
   %msg = %clientId @ " \"" @ escapeString(%message) @ "\"";

   // check for flooding if it's a broadcast OR if it's team in FFA
   if($Server::FloodProtectionEnabled && (!$Server::TourneyMode || !%team))
   {
      // we use getIntTime here because getSimTime gets reset.
      // time is measured in 32 ms chunks... so approx 32 to the sec
      %time = getIntegerTime(true) >> 5;
      if(%clientId.floodMute)
      {
         %delta = %clientId.muteDoneTime - %time;
         if(%delta > 0)
         {
            Client::sendMessage(%clientId, $MSGTypeGame, "FLOOD! You cannot talk for " @ %delta @ " seconds.");
            return;
         }
         %clientId.floodMute = "";
         %clientId.muteDoneTime = "";
      }
      %clientId.floodMessageCount++;
      // funky use of schedule here:
      schedule(%clientId @ ".floodMessageCount--;", 5, %clientId);
      if(%clientId.floodMessageCount > 4)
      {
         %clientId.floodMute = true;
         %clientId.muteDoneTime = %time + 10;
         Client::sendMessage(%clientId, $MSGTypeGame, "FLOOD! You cannot talk for 10 seconds.");
         return;
      }
   }

   if(%team)
   {
      if($dedicated)
         echo("SAYTEAM: " @ %msg);
      %team = Client::getTeam(%clientId);
      for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
         if(Client::getTeam(%cl) == %team && !%cl.muted[%clientId])
            Client::sendMessage(%cl, $MsgTypeTeamChat, %message, %clientId);
   }
   else
   {
      if($dedicated)
         echo("SAY: " @ %msg);
      for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
         if(!%cl.muted[%clientId])
            Client::sendMessage(%cl, $MsgTypeChat, %message, %clientId);
   }
}

[UnderGod]

Ok... First off we are going to need a character to start the command.. TRPG uses #. We will use ! for this purpose.

Code: [Select]

function remoteSay(%clientId, %team, %message)
{
   %msg = %clientId @ " \"" @ escapeString(%message) @ "\"";

   // check for flooding if it's a broadcast OR if it's team in FFA
   if($Server::FloodProtectionEnabled && (!$Server::TourneyMode || !%team))
   {
      // we use getIntTime here because getSimTime gets reset.
      // time is measured in 32 ms chunks... so approx 32 to the sec
      %time = getIntegerTime(true) >> 5;
      if(%clientId.floodMute)
      {
         %delta = %clientId.muteDoneTime - %time;
         if(%delta > 0)
         {
            Client::sendMessage(%clientId, $MSGTypeGame, "FLOOD! You cannot talk for " @ %delta @ " seconds.");
            return;
         }
         %clientId.floodMute = "";
         %clientId.muteDoneTime = "";
      }
      %clientId.floodMessageCount++;
      // funky use of schedule here:
      schedule(%clientId @ ".floodMessageCount--;", 5, %clientId);
      if(%clientId.floodMessageCount > 4)
      {
         %clientId.floodMute = true;
         %clientId.muteDoneTime = %time + 10;
         Client::sendMessage(%clientId, $MSGTypeGame, "FLOOD! You cannot talk for 10 seconds.");
         return;
      }
   }
   
   %Command = False; // We want it to start off on false so things keep ticking

   if(String::getSubStr(%message, 0, 1) == "!") //We are adding this in to see if it has the command sign In this case !
      %command = True; // If it does take a turn down a different road

   %word = GetWord(%message, 0); //We will need this to find out what the command is after the !
   
   if(%command) // The heart of the commands
   {
if(%word == "!tk") // the trigger for the command
{
Client::sendMessage(%TrueClientId, 1, "Team Killing will NOT be tolerated!"); // This will display this message in red to the person who types !tk
return; //We need to make sure !tk isn't displayed in the chat box
}
  else
{
Client::sendMessage(%TrueClientId, 1, "Invalid Command"); This message goes tot he client if they type a command that doesn't exist
return; //We still don't want everyone to see what they are trying to say
    }
    }
   
   if(%team)
   {
      if($dedicated)
         echo("SAYTEAM: " @ %msg);
      %team = Client::getTeam(%clientId);
      for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
         if(Client::getTeam(%cl) == %team && !%cl.muted[%clientId])
            Client::sendMessage(%cl, $MsgTypeTeamChat, %message, %clientId);
   }
   else
   {
      if($dedicated)
         echo("SAY: " @ %msg);
      for(%cl = Client::getFirst(); %cl != -1; %cl = Client::getNext(%cl))
         if(!%cl.muted[%clientId])
            Client::sendMessage(%cl, $MsgTypeChat, %message, %clientId);
   }
}


I hope this helps

[bigbigger9]

Ah, it did. Thanks.

So, in order to make a # kind of thing in base, I just have to add to remoteSay? (on the server right?)

[UnderGod]

Correct.